# Maintainer: Leximus <lcmd@leximus.ru>
# Leximus Commander — двухпанельный файловый менеджер (https://leximus.ru)
# Установка: makepkg -si   (или выложить в AUR как leximus-commander-bin)
pkgname=leximus-commander-bin
pkgver=1.0.1
pkgrel=1
pkgdesc="Fast dual-pane (orthodox) file manager: tabs, archives, FTP/SFTP/WebDAV, folder compare/sync, grep log filter"
arch=('x86_64')
url="https://leximus.ru"
license=('custom')
depends=('glibc' 'zlib' 'openssl' 'icu' 'fontconfig' 'libx11')
provides=('leximus-commander' 'lcmd')
conflicts=('leximus-commander')
options=('!strip' '!debug')
source=("https://leximus.ru/downloads/lcmd-${pkgver}-linux-x64.tar.gz")
sha256sums=('493e12c9d4f3c82dfe1092fa15816a13c945ba075ad7657ce325be9320f2c9cb')

package() {
    local src="${srcdir}/leximus-commander-${pkgver}"
    local opt="${pkgdir}/opt/leximus-commander"

    # Приложение целиком в /opt (self-contained .NET: бинарник + библиотеки + lang)
    install -dm755 "${opt}"
    cp -a "${src}/." "${opt}/"
    rm -f "${opt}/install.sh" "${opt}/leximus-commander.desktop"
    rm -rf "${opt}/icons"
    chmod 755 "${opt}/lcmd"

    # Запуск из PATH
    install -dm755 "${pkgdir}/usr/bin"
    ln -s /opt/leximus-commander/lcmd "${pkgdir}/usr/bin/lcmd"

    # Меню приложений + иконки
    install -Dm644 "${src}/leximus-commander.desktop" \
        "${pkgdir}/usr/share/applications/leximus-commander.desktop"
    for s in 128 256 512; do
        install -Dm644 "${src}/icons/leximus-commander-${s}.png" \
            "${pkgdir}/usr/share/icons/hicolor/${s}x${s}/apps/leximus-commander.png"
    done
}